DEFINITION MODULE Unsigned60 [ZTYPE];

(* Unsigned Integer Subrange Type With Values from 0 to 59 *) 


FROM FileIO IMPORT File; (* required for IO *)


(* Unsigned60 type *)

TYPE
    Unsigned60 = OPAQUE RECORD
        value : OCTET; (* 8 bits *)
    END; (* Unsigned60 *)


(* Z-Type bindings to operators, pervasives and primitives: *)


(* Range *) 

CONST [TMIN] minValue = 0;
(* Smallest value of type Unsigned60.
   This value is bound to TMIN for type Unsigned60. *) 

CONST [TMAX] maxValue = 59;
(* Largest value of type Unsigned60.
   This value is bound to TMAX for type Unsigned60. *)


(* Literal assignment *)

PROCEDURE [:=] assign ( VAR assignTo : Unsigned60; literal : ARRAY OF CHAR );
(* Converts string literal to a Unsigned60 value and assigns it to assignTo.
   This procedure is bound to the := operator for literal assignment. *)


(* Type conversions *)

PROCEDURE [::] toCARD  ( n : Unsigned60 ) : CARDINAL;
(* Converts Unsigned60 value n to a CARDINAL value and returns it.
   This function is bound to the :: operator for Unsigned60 to CARDINAL
   conversion. *)

PROCEDURE [::] toINT ( n : Unsigned60 ) : INTEGER; 
(* Converts Unsigned60 value n to an INTEGER value and returns it.
   This function is bound to the :: operator for Unsigned60 to INTEGER
   conversion. *)

PROCEDURE [::] fromCARD  ( n : CARDINAL ) : Unsigned60;
(* Converts CARDINAL value n to a Unsigned60 value and returns it.
   This function is bound to the :: operator for CARDINAL to Unsigned60
   conversion. *)

PROCEDURE [::] fromINT  ( n : INTEGER ) : Unsigned60;
(* Converts INTEGER value n to a Unsigned60 value and returns it.
   This function is bound to the :: operator for INTEGER to Unsigned60
   conversion. *)


(* Monadic arithmetic operations *) 

PROCEDURE [ODD] odd ( n : Unsigned60 ) : BOOLEAN;
(* Returns TRUE if Unsigned60 value n is odd, otherwise FALSE.
   This function is bound to pervasive function ODD for type Unsigned60. *)


(* Dyadic arithmetic operations *) 

PROCEDURE [+] add ( n1, n2 : Unsigned60 ) : Unsigned60;
(* Adds Unsigned60 values n1 and n2 and returns the result.
   This function is bound to the + operator for type Unsigned60. *)

PROCEDURE [-] sub ( n1, n2 : Unsigned60 ) : Unsigned60;
(* Subtracts Unsigned60 value n2 from n1 and returns the result.
   This function is bound to the - operator for type Unsigned60. *)

PROCEDURE [*] multiply ( n1, n2 : Unsigned60 ) : Unsigned60;
(* Multiplies Unsigned60 values n1 and n2 and returns the result.
   This function it bound to the * operator for type Unsigned60. *)

PROCEDURE [/] divide ( n1, n2 : Unsigned60 ) : Unsigned60;
(* Divives Unsigned60 value n1 by n2 and returns the result.
   This function is bound to the / operator for type Unsigned60. *)


(* Relational operations *) 

PROCEDURE [=] isEqual ( n1, n2 : Unsigned60 ) : BOOLEAN;
(* Returns TRUE if Unsigned60 values n1 and n2 are equal, otherwise FALSE.
   This function is bound to operators = and # for type Unsigned60. *)

PROCEDURE [<] isLess ( n1, n2 : Unsigned60 ) : BOOLEAN;
(* Returns TRUE if Unsigned60 value n1 is less than n2, otherwise FASLE.
   This function is bound to operators < and >= for type Unsigned60. *)

PROCEDURE [>] isGreater ( n1, n2 : Unsigned60 ) : BOOLEAN;
(* Returns TRUE if Unsigned60 value n1 is greater than n2, otherwise FALSE.
   This function is bound to operators > and <= for type Unsigned60. *)


(* Scalar conversion primitives *)

CONST digitCapacity = 2; (* maximum digits in native format *)

PROCEDURE [TO] toSXF ( n : Unsigned60; VAR s : ARRAY OF CHAR );
(* Converts Unsigned60 value n to a string in scalar exchange format.
   This procedure is used to synthesise conversions to other scalar types
   when no direct conversion path exists. *)

PROCEDURE [FROM] fromSXF ( VAR n : Unsigned60; CONST s : ARRAY OF CHAR );
(* Converts a string in scalar exchange format to a Unsigned60 value.
   This procedure is used to synthesise conversions from other scalar types
   when no direct conversion path exists. *)


(* IO operations *)

PROCEDURE Read( infile : File; VAR n : Unsigned60 );
(* Reads the textual representation of a Unsigned60 value from stream infile
   - any leading whitespace is skipped
   - any remaining characters that are part of the numeral being read are
     removed from infile
   - the numeric value of the numeral string read is assigned to the variable
     passed in for n
   - the file status is set to any of:
     success, outOfRange, wrongFormat, endOfLine, or endOfInput.
   This procedure is substituted for invocations of READ with a Unsigned60
   argument. *)

PROCEDURE Write( outfile : File; n : Unsigned60 );
(* Writes the textual representation of value n to stream outfile.
   This procedure is substituted for invocations of WRITE with a Unsigned60
   argument. *)

PROCEDURE WriteF ( outfile      : File;
                   CONST fmtStr : ARRAY OF CHAR;
                   items        : VARIADIC OF Unsigned60 );
(* Writes a formatted textual representation of one or more Unsigned60 values
   to output stream outfile. The output format is determined by fmtStr. This
   procedure is substituted for invocations of WRITEF with one or more
   Unsigned60 arguments. *)

END Unsigned60.