Modula-2 Reloaded

A Modern Typesafe & Literate Programming Notation

Site Menu

Project

Specification

Implementation

Recommendations

Reference

Needs Updating

Work in Progress

Wastebasket

Wiki Manual

edit SideBar

CARD 16

DEFINITION MODULE CARD16 [ZTYPE];

(* 16-bit Unsigned Integer Numbers *) 


FROM FileIO IMPORT File; (* required for IO *)


(* CARD16 type *)

TYPE
    CARD16 = OPAQUE RECORD
        value : ARRAY 2 OF OCTET; (* 16 bits *)
    END; (* CARD16 *)


(* Z-Type bindings to operators, pervasives and primitives: *)


(* Range *) 

CONST [TMIN] minValue = 0;
(* Smallest value of type CARD16.
   This value is bound to TMIN for type CARD16. *) 

CONST [TMAX] maxValue = 65535;
(* Largest value of type CARD16.
   This value is bound to TMAX for type CARD16. *)


(* Literal assignment *)

PROCEDURE [:=] assign ( VAR assignTo : CARD16; literal : ARRAY OF CHAR );
(* Converts string literal to a CARD16 value and assigns it to assignTo.
   This procedure is bound to the := operator for literal assignment. *)


(* Type conversions *)

PROCEDURE [::] toCARD  ( n : CARD16 ) : CARDINAL;
(* Converts CARD16 value n to a CARDINAL value and returns it. This
   function is bound to the :: operator for CARD16 to CARDINAL conversion.*)

PROCEDURE [::] toINT ( n : CARD16 ) : INTEGER; 
(* Converts CARD16 value n to an INTEGER value and returns it. This
   function is bound to the :: operator for CARD16 to INTEGER conversion. *)

PROCEDURE [::] fromCARD  ( n : CARDINAL ) : CARD16;
(* Converts CARDINAL value n to a CARD16 value and returns it. This function
   is bound to the :: operator for CARDINAL to CARD16 conversion. *)

PROCEDURE [::] fromINT  ( n : INTEGER ) : CARD16;
(* Converts INTEGER value n to a CARD16 value and returns it. This function
   is bound to the :: operator for INTEGER to CARD16 conversion. *)


(* Monadic arithmetic operations *) 

PROCEDURE [ABS] abs ( n : CARD16 ) : CARD16;
(* Returns the absolute value of CARD16 value n.
   This function is bound to pervasive function ABS for type CARD16. *)

PROCEDURE [ODD] odd ( n : CARD16 ) : BOOLEAN;
(* Returns TRUE if CARD16 value n is odd, otherwise FALSE.
   This function is bound to pervasive function ODD for type CARD16. *)


(* Dyadic arithmetic operations *) 

PROCEDURE [+] add ( n1, n2 : CARD16 ) : CARD16;
(* Adds CARD16 values n1 and n2 and returns the result.
   This function is bound to the + operator for type CARD16. *)

PROCEDURE [-] sub ( n1, n2 : CARD16 ) : CARD16;
(* Subtracts CARD16 value n2 from n1 and returns the result.
   This function is bound to the - operator for type CARD16. *)

PROCEDURE [*] multiply ( n1, n2 : CARD16 ) : CARD16;
(* Multiplies CARD16 values n1 and n2 and returns the result.
   This function it bound to the * operator for type CARD16. *)

PROCEDURE [/] divide ( n1, n2 : CARD16 ) : CARD16;
(* Divives CARD16 value n1 by n2 and returns the result.
   This function is bound to the / operator for type CARD16. *)


(* Relational operations *) 

PROCEDURE [=] isEqual ( n1, n2 : CARD16 ) : BOOLEAN;
(* Returns TRUE if CARD16 values n1 and n2 are equal, otherwise FALSE.
   This function is bound to operators = and # for type CARD16. *)

PROCEDURE [<] isLess ( n1, n2 : CARD16 ) : BOOLEAN;
(* Returns TRUE if CARD16 value n1 is less than n2, otherwise FASLE.
   This function is bound to operators < and >= for type CARD16. *)

PROCEDURE [>] isGreater ( n1, n2 : CARD16 ) : BOOLEAN;
(* Returns TRUE if CARD16 value n1 is greater than n2, otherwise FALSE.
   This function is bound to operators > and <= for type CARD16. *)


(* Scalar conversion primitives *)

CONST digitCapacity = 4; (* maximum digits in native format *)

PROCEDURE [TO] toSXF ( n : CARD16; VAR s : ARRAY OF CHAR );
(* Converts CARD16 value n to a string in scalar exchange format.
   This procedure is used to synthesise conversions to other scalar types
   when no direct conversion path exists. *)

PROCEDURE [FROM] fromSXF ( VAR n : CARD16; CONST s : ARRAY OF CHAR );
(* Converts a string in scalar exchange format to a CARD16 value.
   This procedure is used to synthesise conversions from other scalar types
   when no direct conversion path exists. *)


(* IO operations *)

PROCEDURE Read( infile : File; VAR n : CARD16 );
(* Reads the textual representation of a CARD16 value from stream infile
   - any leading whitespace is skipped
   - any remaining characters that are part of the numeral being read are
     removed from infile
   - the numeric value of the numeral string read is assigned to the variable
     passed in for n
   - the file status is set to any of:
     success, outOfRange, wrongFormat, endOfLine, or endOfInput. This
   procedure is substituted for invocations of READ with a CARD16 argument. *)

PROCEDURE Write( outfile : File; n : CARD16 );
(* Writes the textual representation of value n to stream outfile. This
   procedure is substituted for invocations of WRITE with a CARD16 argument.*)

PROCEDURE WriteF ( outfile      : File;
                   CONST fmtStr : ARRAY OF CHAR;
                   items        : VARIADIC OF CARD16 );
(* Writes a formatted textual representation of one or more CARD16 values to
   output stream outfile. The output format is determined by fmtStr. This
   procedure is substituted for invocations of WRITEF with one or more
   CARD16 arguments. *)

END CARD16.